At the request of MacSparky, I've put together a few AppleScripts for Mac Mail users, to mark messages as read...
Script 1: Mail • Mark All Inbox Messages Read
tell application "Mail"
set read status of every message of inbox to true
end tell
Script 2: Mail • Mark All Messages Read
display alert "Please note!" message "This script may take a while if you have a ton of mailboxes. Do you want to continue?" buttons {"Cancel", "Yes"} cancel button "Cancel"
with timeout of 600 seconds
tell application "Mail"
set read status of every message of inbox where its read status = false to true
set read status of every message of every ¬
mailbox where its read status = false to true
set read status of every message of every mailbox ¬
of every account where its read status = false to true
end tell
end timeout
Script 3: Mail • Mark Selected Mailbox Messages Read
display alert "Please note!" message "This script may take a while if you have a lot of mailboxes selected. Do you want to continue?" buttons {"Cancel", "Yes"} cancel button "Cancel"
set processSubMailboxes to (button returned of (display alert "Would you like to scan all submailboxes too?" message "Again, if you have a lot of selected mailboxes and submailboxes, this may take a while." buttons {"Yes", "No"})) = "Yes"
tell application "Mail"
tell front message viewer
set theSelectedMailboxes to selected mailboxes
repeat with a from 1 to length of theSelectedMailboxes
set theCurrentMailbox to item a of theSelectedMailboxes
processMailbox(theCurrentMailbox, processSubMailboxes) of me
end repeat
end tell
end tellon processMailbox(theMailbox, processSubMailboxes)
tell application "Mail"
if processSubMailboxes = true then
set theSubMailboxes to every mailbox of theMailbox
repeat with a from 1 to length of theSubMailboxes
set theCurrentSubMailbox to item a of theSubMailboxes
processMailbox(theCurrentSubMailbox, processSubMailboxes) of me
end repeat
end if
set read status of every message of theMailbox to true
end tell
end processMailbox
Usage
You can download these scripts here.
You can quickly and easily run them from the system-wide AppleScript menu. This menu is not enabled by default. To enable it and install the scripts...
- Launch AppleScript Editor in /Applications/Utilities
- Select AppleScript Editor > Preferences from the menu bar
- Under General, click the Show Script Menu in the Menu Bar checkbox
- Bring Mail to the front
- From the script menu, choose Open Scripts Folder > Open Mail Scripts Folder
- Copy the scripts into the folder. They will now be available from the script menu when you're working in Mail
Enjoy!
-Ben